Public WithEvents PLine As AcadLWPolyline    ' Использование примера События Modified
Sub Example_Modified()
     ' Этот пример создает легкую ломаную линию в пространстве модели и
     ' перехватывает событие Modified.
     '
     'Этот пример затем изменяет новый объект, вызывая код в событии Modified.
    
    Dim points(0 To 9) As Double
    
    'Определите 2D точки ломаной линии
    points(0) = 1: points(1) = 1
    points(2) = 1: points(3) = 2
    points(4) = 2: points(5) = 2
    points(6) = 3: points(7) = 2
    points(8) = 4: points(9) = 4
        
    'Создайте легкий объект Polyline в пространстве модели
    '
    '* Примечание: Мы возвращаем новый объект PolyLine в переменную
    ' уровня Модуля. Это позволяет нам перехватывать события, связанные с
    ' тем специфическим объектом.
    Set PLine = ThisDrawing.ModelSpace.AddLightWeightPolyline(points)
    
    ThisDrawing.Application.ZoomAll
    
    'Измените объект, чтобы вызвать событие.
    '
    '* Примечание: код события для модификации PolyLine будет вызван
    ' прежде, чем мы продвигаемся и обновляем вид, таким образом линия не
    ' будет казаться синей, когда окно сообщения события показано.
    Dim color As AcadAcCmColor
    Set color = AcadApplication.GetInterfaceObject("AutoCAD.AcCmColor.16")
    Call color.SetRGB(80, 100, 244)
    PLine.TrueColor = color

    ThisDrawing.Regen acAllViewports
    
End Sub

Private Sub PLine_Modified(ByVal pObject As AutoCAD.IAcadObject)
    'Этот пример перехватывает событие объекта Modified.
    '
    'Это событие вызвано, когда объект, поддерживающий это событие изменен.
    '
    'Чтобы вызвать этот код: Измените объект, связанный с этим событием
    '* Примечание: связанным, мы подразумеваем объект, установленный,
    ' чтобы перехватить события, используя VBA WithEvents утверждение

    'Используйте "pObject" переменную, чтобы определить, какой объект был изменен
    MsgBox "Вы только изменили объект ID: " & pObject.ObjectID
    
End Sub

Сайт управляется системой uCoz