Sub Example_ActiveViewport()
    ' Этот пример возвращает текущую область просмотра.
    ' Он создает новую область просмотра и делает её активной и затем
    ' разбивает область просмотра на четыре окна.
    ' Затем берет одно из этих четырех окон, и разбивает 'то окно
    ' горизонтально на половины.
    Dim currViewport As AcadViewport
    Dim newViewport As AcadViewport
    
    ' Возращается текущая область просмотра активного документа
    Set currViewport = ThisDrawing.ActiveViewport
    MsgBox "Текущая область просмотра " & currViewport.name, vbInformation, "ActiveViewport Пример"
    
    ' Создайте новую область просмотра и сделайте её активной
    Set newViewport = ThisDrawing.Viewports.Add("TESTVIEWPORT")
    ThisDrawing.ActiveViewport = newViewport
    MsgBox "Новая активная область просмотра " & newViewport.name, vbInformation, "ActiveViewport Пример"
    
    ' Разбейте область просмотра на четыре окна
    newViewport.Split acViewport4
    
    ' Сделайте недавно разбитую область просмотра активной
    ThisDrawing.ActiveViewport = newViewport
    
    ' Обратите внимание, что лист текущего рисунка покажет четыре окна.
    ' Однако, только одно из окон будет активно.
    ' Следующий код сделает левое нижнее окно активным и затем разобьёт
    ' его на два горизонтальных окна.
    Dim entry
    For Each entry In ThisDrawing.Viewports
        If entry.name = "TESTVIEWPORT" Then
            Dim lowerLeft
            lowerLeft = entry.LowerLeftCorner
            If lowerLeft(0) = 0 And lowerLeft(1) = 0 Then
                Set newViewport = entry
                Exit For
            End If
        End If
    Next
    newViewport.Split acViewport2Horizontal
    ThisDrawing.ActiveViewport = newViewport
End Sub