Sub Example_Alignment()
   ' Этот пример создает текстовый объект в пространстве модели
   ' и демонстрирует установку выравнивания новой текстовой строки
    
    Dim textObj As AcadText
    Dim textString As String
    Dim insertionPoint(0 To 2) As Double, alignmentPoint(0 To 2) As Double
    Dim height As Double
    Dim oldPDMODE As Integer
    Dim pointObj As AcadPoint
    
    ' Определите новый объект Text
    textString = "Hello, World."
    insertionPoint(0) = 3: insertionPoint(1) = 3: insertionPoint(2) = 0
    alignmentPoint(0) = 3: alignmentPoint(1) = 3: alignmentPoint(2) = 0
    height = 0.5
    
    ' Создайте объект Text в пространстве модели
    Set textObj = ThisDrawing.ModelSpace.AddText(textString, insertionPoint, height)
    
    oldPDMODE = ThisDrawing.GetVariable("PDMODE")   ' Record existing point style
    
    ' Создайте перекрестие в точке выравнивания текста, чтобы лучше
    ' визуализировать процесс выравнивания
    Set pointObj = ThisDrawing.ModelSpace.AddPoint(alignmentPoint)
    
    ThisDrawing.SetVariable "PDMODE", 2             ' Установленный стиль точки к перекрестию
        
    ThisDrawing.Application.ZoomAll
    
    ' Установите выравнивание текста на другое значение кроме
    ' acAlignmentLeft, которое является значением по умолчанию.
    ' Создайте точку, которая будет действовать как контрольная точка выравнивания
    textObj.Alignment = acAlignmentRight
    
    ' Создайте контрольную точку выравнивания текста и текст автоматически
    ' выровняется в направлении от этой точки, потому что выравнивание
    ' текста было установлено в acAlignmentRight
    textObj.TextAlignmentPoint = alignmentPoint
    ThisDrawing.Regen acActiveViewport
    MsgBox "Объект Text теперь выровнен вправо от точки выравнивания"
    
    ' Выровняйте по центру текст к точке выравнивания
    textObj.Alignment = acAlignmentCenter
    ThisDrawing.Regen acActiveViewport
    MsgBox "Объект Text теперь центрирован к точке выравнивания"
    
    ' Сбросьте стиль точки
    ThisDrawing.SetVariable "PDMODE", oldPDMODE
End Sub