Sub Example_AppendInnerLoop()
    ' Этот пример создает ассоциативную штриховку в пространстве модели и
    ' затем добавляет в конец внешний цикл к штриховке.
    
    Dim hatchObj As AcadHatch
    Dim patternName As String
    Dim PatternType As Long
    Dim bAssociativity As Boolean
    
    ' Определите штриховку
    patternName = "ANSI31"
    PatternType = 0
    bAssociativity = True
    
    ' Создайте ассоциативный объект Hatch
    Set hatchObj = ThisDrawing.ModelSpace.AddHatch(PatternType, patternName, bAssociativity)
    
    ' Создайте внешний цикл для штриховки.
    ' Дуга и линия используются, чтобы создать петлю.
    
    Dim outerLoop(0 To 1) As AcadEntity
    Dim center(0 To 2) As Double
    Dim radius As Double
    Dim startAngle As Double
    Dim endAngle As Double
    center(0) = 5: center(1) = 3: center(2) = 0
    radius = 3
    startAngle = 0
    endAngle = 3.141592
    Set outerLoop(0) = ThisDrawing.ModelSpace.AddArc(center, radius, startAngle, endAngle)
    Set outerLoop(1) = ThisDrawing.ModelSpace.AddLine(outerLoop(0).startPoint, outerLoop(0).endPoint)
        
    ' Добавьте в конец внешний цикл к объекту штриховки
    hatchObj.AppendOuterLoop (outerLoop)
    
    ' Добавьте в конец круг как внутренний цикл для штриховки.
    Dim innerLoop(0) As AcadEntity
    center(0) = 5: center(1) = 4.5: center(2) = 0
    radius = 1
    Set innerLoop(0) = ThisDrawing.ModelSpace.AddCircle(center, radius)
    hatchObj.AppendInnerLoop (innerLoop)
    
    ' Оцените и покажите штриховку
    hatchObj.Evaluate
    ThisDrawing.Regen True
    
End Sub