Sub Example_ArrowHead2Type()
    ' Этот пример создает объект Dim3PointAngular в пространстве модели и
    ' затем изменяет видимый вид (форму) его стрелок - указателей, используя
    ' свойства ArrowHead2Type и ArrowHead1Type
    
    Dim DimPointAngularObj As AcadDim3PointAngular
    Dim AngleVertex(0 To 2) As Double
    Dim FirstPoint(0 To 2) As Double, SecondPoint(0 To 2) As Double
    Dim TextPoint(0 To 2) As Double
    
    ' Определите новый объект Dim3PointAngular
    AngleVertex(0) = 0: AngleVertex(1) = 0: AngleVertex(2) = 0
    FirstPoint(0) = 2: FirstPoint(1) = 2: FirstPoint(2) = 0
    SecondPoint(0) = 1: SecondPoint(1) = 4: SecondPoint(2) = 0
    TextPoint(0) = 6: TextPoint(1) = 6: TextPoint(2) = 0

    ' Создайте новый объект Dim3PointAngular в пространстве модели
    Set DimPointAngularObj = ThisDrawing.ModelSpace.AddDim3PointAngular(AngleVertex, FirstPoint, SecondPoint, TextPoint)
    ThisDrawing.Application.ZoomAll

    ' Читайте и показывайте текущий тип стрелки - указателя
    MsgBox "Тип стрелки - указателя для первой стрелки этого объекта: " & DimPointAngularObj.Arrowhead1Type & vbCrLf & _
           "Тип стрелки - указателя для второй стрелки этого объекта: " & DimPointAngularObj.Arrowhead2Type

    ' Измените свойство типа стрелки - указателя для обеих стрелок этого объекта
    DimPointAngularObj.Arrowhead1Type = acArrowBoxBlank
    DimPointAngularObj.Arrowhead2Type = acArrowBoxBlank
    ThisDrawing.Regen acAllViewports
    
    ' Читайте и показывайте текущий тип стрелки - указателя
    MsgBox "Тип стрелки - указателя для первой стрелки этого объекта теперь установлен в: " & DimPointAngularObj.Arrowhead1Type & vbCrLf & _
           "Тип стрелки - указателя для второй стрелки этого объекта теперь установлен в: " & DimPointAngularObj.Arrowhead2Type
End Sub