Sub Example_ArrowHeadType()
    ' Этот пример создает объект Leader в пространстве модели со связанным
    ' Annotation и затем изменяет видимую форму его стрелки - указателя,
    ' используя свойство ArrowHeadType

    Dim leaderObj As AcadLeader, MTextObj As AcadMText
    Dim points(0 To 8) As Double, insertionPoint(0 To 2) As Double, iTextWidth As Double
    Dim leaderType As Integer
    Dim annotationObject As Object
    Dim textString As String
    
    ' Определите новый объект MText
    textString = "Hello, World."
    insertionPoint(0) = 5: insertionPoint(1) = 5: insertionPoint(2) = 0
    iTextWidth = 2
    
    ' Создайте объект MText в пространстве модели
    Set MTextObj = ThisDrawing.ModelSpace.AddMText(insertionPoint, iTextWidth, textString)
    
    ' Данные для Выноски
    points(0) = 0: points(1) = 0: points(2) = 0
    points(3) = 4: points(4) = 4: points(5) = 0
    points(6) = 4: points(7) = 5: points(8) = 0
    leaderType = acLineWithArrow
       
    ' Создайте объект Leader в пространстве модели, и cвяжите новый объект
    ' MText с новой Выноской, делая объект MText аннотацией для Выноски
    Set annotationObject = MTextObj
    Set leaderObj = ThisDrawing.ModelSpace.AddLeader(points, annotationObject, leaderType)
    ThisDrawing.Application.ZoomAll

    ' Читайте и показывайте текущий тип стрелки - указателя
    MsgBox "Тип стрелки - указателя для этого объекта: " & leaderObj.ArrowheadType

    ' Измените свойство типа стрелки - указателя для этого объекта
    leaderObj.ArrowheadType = acArrowBoxBlank
    ThisDrawing.Application.ZoomAll
    
    ' Читайте и показывайте текущий тип стрелки - указателя
    MsgBox "Тип стрелки - указателя для этого объекта теперь установлен в: " & leaderObj.ArrowheadType
End Sub