Sub Example_AttachToolbarToFlyout()
    ' Этот пример использует MenuGroups, чтобы получить справочник к главному меню AutoCADа.
    ' Затем создает нового Toolbar (TestMenu) с кнопкой Toolbar, которая будет
    ' действовать как выпадающая панель. Затем устанавливает меню Flyout
    ' для существующего меню Toolbar.
    ' Toolbar будет автоматически показан и покажет меню UCS как
    ' выпадающая панель.
        
    Dim currMenuGroup As acadMenuGroup
    Dim newToolBar As AcadToolbar, newToolBarFlyoutButton As AcadToolbarItem
    
    On Error GoTo ERRORTRAP
    
    ' Используйте свойство MenuGroups, чтобы получить справочник к основному меню AutoCAD
    Set currMenuGroup = ThisDrawing.Application.MenuGroups.Item("ACAD")
    
    ' Создайте нового Toolbar в этой группе
    Set newToolBar = currMenuGroup.Toolbars.Add("TestMenu")
    
    ' Добавьте новую кнопку к TestMenu, который свяжется с меню Flyout
    '
    ' * ПРИМЕЧАНИЕ: Установите макро название к названию панели
    ' инструментов выпадающей панели, потому что установка этого к пустой
    ' строке вызывает ошибку. Параметр фактически игнорируется, когда стиль 
    ' - выпадающая панель, но должен иметь любое значение отличное от "".
    Set newToolBarFlyoutButton = newToolBar.AddToolbarButton(newToolBar.count + 1, "Flyout", "Flyout", "UCS", True)
    
    ' Свяжите существующий "UCS" панели инструментов как выпадающая
    ' панель для новой кнопки панели
    '
    ' * ПРИМЕЧАНИЕ: Чтобы изменять выпадающую панель, просто измените
    ' MenuGroup и название Toolbar ниже
    newToolBarFlyoutButton.AttachToolbarToFlyout "ACAD", "UCS"
   
    MsgBox "Новый Toolbar с выпадающей панелью добавился к системе меню AutoCAD! "
    
    Exit Sub

ERRORTRAP:
    MsgBox "Произошла следующая ошибка: " & Err.Description
End Sub

Сайт управляется системой uCoz