Sub Example_ConfigName()
    ' Этот пример добавит новую конфигурацию печати к текущему рисунку.
    ' Он перечислит имя файла конфигурации плоттера для каждого Layout в
    ' текущем рисунке, изменит конфигурацию для Layout1 к "DWF Classic.pc3"
    ' и восстановит изображение информации конфигурации для рисунка.
    '
    ' * Примечание: Имена файла могут отличаться на вашей системе, так вы
    ' должны быть готовы изменить имя файла конфигурации, используемое в
    ' примере к файлу, который существует на вашей системе.

    Dim Layouts As AcadLayouts, Layout As ACADLayout
    Dim msg As String
    Dim ACADPref As AcadPreferencesFiles
    Dim originalValue As Variant
    
    ' Получите объект параметров файлов
    Set ACADPref = ThisDrawing.Application.preferences.Files

    ' Читайте и показывайте первоначальное значение
    originalValue = ACADPref.PrinterConfigPath
    
    ' Получите коллекцию листов от объекта документа
    Set Layouts = ThisDrawing.Layouts
    
    ' Покажите текущую информацию конфигурации плоттера
    GoSub DISPLAY_CONFIG
    
    ' Файл конфигурации плоттера изменения для "Layout1"
    Layouts("Layout1").ConfigName = "DWF Classic.pc3"
    
    ' Покажите новую информацию конфигурации плоттера
    GoSub DISPLAY_CONFIG
    
    Exit Sub
        
DISPLAY_CONFIG:
    msg = vbCrLf & vbCrLf
    
    ' Формат и текущий каталог отображения для файлов конфигурации
    msg = msg & vbTab & "Каталоги, которые будут просмотрены для файлов конфигурации плоттера: " _
                & vbCrLf & vbTab & vbTab & originalValue & vbCrLf & vbCrLf
    
    ' Получите название конфигурации плоттера каждого листа в этом рисунке
    For Each Layout In Layouts
        ' Формат для отображения
        msg = msg & vbTab & Layout.name & " использует конфигурацию: " & Layout.ConfigName & vbCrLf
    Next
    
    ' Покажите бумажную информацию единиц
    MsgBox "Информация конфигурации плоттера, используемая в текущем рисунке упомянута ниже." & msg
    
    Return
End Sub

Сайт управляется системой uCoz