Sub Example_DecimalSeparator()
    ' Этот пример создает объект Dim3PointAngular в пространстве модели и
    ' позволяет пользователю изменять десятичный вид разделителя,
    ' используя свойство DecimalSeparator
    
    Dim DimPointAngularObj As AcadDim3PointAngular
    Dim AngleVertex(0 To 2) As Double
    Dim FirstPoint(0 To 2) As Double, SecondPoint(0 To 2) As Double
    Dim TextPoint(0 To 2) As Double
    Dim oldSeparator As String, newSeparator As String
    
    ' Определите новый объект Dim3PointAngular
    AngleVertex(0) = 0: AngleVertex(1) = 0: AngleVertex(2) = 0
    FirstPoint(0) = 2: FirstPoint(1) = 2: FirstPoint(2) = 0
    SecondPoint(0) = 1: SecondPoint(1) = 4: SecondPoint(2) = 0
    TextPoint(0) = 6: TextPoint(1) = 6: TextPoint(2) = 0

    ' Создайте новый объект Dim3PointAngular в пространстве модели
    Set DimPointAngularObj = ThisDrawing.ModelSpace.AddDim3PointAngular(AngleVertex, FirstPoint, SecondPoint, TextPoint)
    
    ' Точность набора такая, чтобы градусы были видимы
    DimPointAngularObj.TextPrecision = acDimPrecisionFour
    
    ThisDrawing.Application.ZoomAll

    ' Читайте и показывайте текущий десятичный разделитель
    MsgBox "Десятичный разделитель для этого объекта в настоящее время установлен в: [" & DimPointAngularObj.DecimalSeparator & "]"

    ' Измените десятичное свойство разделителя для этого объекта
    oldSeparator = DimPointAngularObj.DecimalSeparator
    newSeparator = InputBox("Введите новый десятичный разделитель", "Измените Десятичный Разделитель", oldSeparator)
    
    If newSeparator = "" Then
        Exit Sub
    Else
        ' Удостоверьтесь, что был использован только один символ
        DimPointAngularObj.DecimalSeparator = Left(newSeparator, 1)
    End If
    
    ThisDrawing.Regen acAllViewports
    
    ' Читайте и показывайте текущий десятичный разделитель
    MsgBox "Десятичный разделитель для этого объекта теперь установлен в: [" & DimPointAngularObj.DecimalSeparator & "]"
End Sub