Sub Example_DimensionLineWeight()
    ' Этот пример создает объект Dim3PointAngular в пространстве модели и
    ' изменяет вес линии на большее значение, используя свойство
    ' DimensionLineWeight
    
    Dim DimPointAngularObj As AcadDim3PointAngular
    Dim AngleVertex(0 To 2) As Double
    Dim FirstPoint(0 To 2) As Double, SecondPoint(0 To 2) As Double
    Dim TextPoint(0 To 2) As Double
    Dim oldLWSetting As Boolean
    Dim CurrentSetting As String
        
    ' Включите отображение веса линии, так что изменения могут быть замечены
    oldLWSetting = ThisDrawing.preferences.LineWeightDisplay
    ThisDrawing.preferences.LineWeightDisplay = True
    
    ' Определите новый объект Dim3PointAngular
    AngleVertex(0) = 0: AngleVertex(1) = 0: AngleVertex(2) = 0
    FirstPoint(0) = 2: FirstPoint(1) = 2: FirstPoint(2) = 0
    SecondPoint(0) = 1: SecondPoint(1) = 4: SecondPoint(2) = 0
    TextPoint(0) = 6: TextPoint(1) = 6: TextPoint(2) = 0

    ' Создайте новый объект Dim3PointAngular в пространстве модели
    Set DimPointAngularObj = ThisDrawing.ModelSpace.AddDim3PointAngular(AngleVertex, FirstPoint, SecondPoint, TextPoint)
    ThisDrawing.Application.ZoomAll

    ' Читайте и показывайте текущий вес линии измерения
    CurrentSetting = DimPointAngularObj.DimensionLineWeight
    Select Case CurrentSetting
        Case acLnWtByLayer: CurrentSetting = "By Layer"
        Case acLnWtByBlock: CurrentSetting = "By Block"
        Case acLnWtByLwDefault: CurrentSetting = "By Default"
        Case Else
    End Select

    MsgBox "Установка веса линии измерения для этого объекта в настоящее время установлена в: " & CurrentSetting

    ' Измените вес линии измерения
    DimPointAngularObj.DimensionLineWeight = acLnWt100
    ThisDrawing.Regen acAllViewports
    
    ' Читайте и показывайте текущий вес линии измерения
    MsgBox "Установка веса линии измерения для этого объекта теперь установлена в: " & DimPointAngularObj.DimensionLineWeight
    
    ' Возвратите предыдущую установку веса линии
    ThisDrawing.preferences.LineWeightDisplay = oldLWSetting

End Sub