Sub Example_DimensionLine1Suppress()
    ' Этот пример создает объект Dim3PointAngular в пространстве модели и
    ' подавляет линии измерения, используя свойства DimensionLine2Suppress
    ' и DimensionLine1Suppress
    
    Dim DimPointAngularObj As AcadDim3PointAngular
    Dim AngleVertex(0 To 2) As Double
    Dim FirstPoint(0 To 2) As Double, SecondPoint(0 To 2) As Double
    Dim TextPoint(0 To 2) As Double
    Dim Line1Suppressed As String, Line2Suppressed As String
    
    ' Определите новый объект Dim3PointAngular
    AngleVertex(0) = 0: AngleVertex(1) = 0: AngleVertex(2) = 0
    FirstPoint(0) = 2: FirstPoint(1) = 2: FirstPoint(2) = 0
    SecondPoint(0) = 1: SecondPoint(1) = 4: SecondPoint(2) = 0
    TextPoint(0) = 6: TextPoint(1) = 6: TextPoint(2) = 0

    ' Создайте новый объект Dim3PointAngular в пространстве модели
    Set DimPointAngularObj = ThisDrawing.ModelSpace.AddDim3PointAngular(AngleVertex, FirstPoint, SecondPoint, TextPoint)
    ThisDrawing.Application.ZoomAll

    ' Читайте и показывайте текущую информацию подавления линии
    Line1Suppressed = IIf(DimPointAngularObj.DimLine1Suppress, "подавлена", "не подавлена")
    Line2Suppressed = IIf(DimPointAngularObj.DimLine2Suppress, "подавлена", "не подавлена")
    
    MsgBox "Первыя линия измерения " & Line1Suppressed & vbCrLf & _
           "Вторая линия измерения " & Line2Suppressed

    ' Подавите, выравнивают одно из измерения
    DimPointAngularObj.DimLine1Suppress = True
    ThisDrawing.Regen acAllViewports
    MsgBox "Первыя линия измерения, теперь подавлена"
    
    ' Подавите вторую линию измерения
    DimPointAngularObj.DimLine2Suppress = True
    ThisDrawing.Regen acAllViewports
    MsgBox "Вторая линия измерения теперь подавлена"
   
    ' Возвратите обе линии измерения
    DimPointAngularObj.DimLine1Suppress = False
    DimPointAngularObj.DimLine2Suppress = False
    ThisDrawing.Regen acAllViewports
    MsgBox "Обе линии измерения теперь видимы снова"

End Sub