Sub Example_DockStatus()
    ' Этот пример создает новую панель инструментов по имени "TestToolbar" и 
    ' вставляет три кнопки. Панель инструментов показана как плавающая и
    ' затем как состыкованная панель инструментов.
    ' Чтобы удалить панель инструментов после выполнения этой
    ' макрокоманды, используйте опцию Customize Menu меню Tools.
    
    Dim currMenuGroup As acadMenuGroup
    Set currMenuGroup = ThisDrawing.Application.MenuGroups.Item(0)
    
    ' Создайте новую панель инструментов
    Dim newToolBar As AcadToolbar
    Set newToolBar = currMenuGroup.Toolbars.Add("TestToolbar")
    
    ' Добавьте три кнопки к новой панели инструментов.
    ' Всем трем кнопкам прикрепить ту же макрокоманду.
    Dim newButton1 As AcadToolbarItem
    Dim newButton2 As AcadToolbarItem
    Dim newButton3 As AcadToolbarItem
    Dim openMacro As String
    
    ' Назначите макро строку эквивалент "ESC ESC _open "
    openMacro = Chr(3) & Chr(3) & Chr(95) & "open" & Chr(32)
    
    Set newButton1 = newToolBar.AddToolbarButton("", "NewButton1", "Откройте файл.", openMacro)
    Set newButton2 = newToolBar.AddToolbarButton("", "NewButton2", "Откройте файл.", openMacro)
    Set newButton3 = newToolBar.AddToolbarButton("", "NewButton3", "Откройте файл.", openMacro)
    
    
    ' Покажите панель инструментов
    newToolBar.Visible = True
    
    ' Закрепите панель инструментов слева от экрана.
    newToolBar.Dock acToolbarDockLeft
    GoSub QUERYSTATUS
    
    ' С плавающей точкой панель инструментов
    newToolBar.Float 200, 200, 1
    GoSub QUERYSTATUS
    
    Exit Sub
    
QUERYSTATUS:
    ' Сделайте запрос панели инструментов, чтобы видеть, закрепляется ли она.
    If newToolBar.DockStatus = acToolbarFloating Then
        MsgBox "Панель инструментов является плавающей."
    Else
        MsgBox "Панель инструментов закрепляется."
    End If
    Return
    
End Sub

Сайт управляется системой uCoz