Sub Example_ExtensionLineWeight()
    ' Этот пример создает объект Dim3PointAngular в пространстве модели и
    ' изменяет вес линии расширения на более толстое значение, используя
    ' свойство ExtensionLineWeight
    
    Dim DimPointAngularObj As AcadDim3PointAngular
    Dim AngleVertex(0 To 2) As Double
    Dim FirstPoint(0 To 2) As Double, SecondPoint(0 To 2) As Double
    Dim TextPoint(0 To 2) As Double
    Dim oldLWSetting As Boolean
    Dim CurrentSetting As String
    
    ' Включите отображение веса линии, чтобы видеть изменения
    oldLWSetting = ThisDrawing.preferences.LineWeightDisplay
    ThisDrawing.preferences.LineWeightDisplay = True
    
    ' Определите новый объект Dim3PointAngular
    AngleVertex(0) = 0: AngleVertex(1) = 0: AngleVertex(2) = 0
    FirstPoint(0) = 2: FirstPoint(1) = 2: FirstPoint(2) = 0
    SecondPoint(0) = 1: SecondPoint(1) = 4: SecondPoint(2) = 0
    TextPoint(0) = 6: TextPoint(1) = 6: TextPoint(2) = 0

    ' Создайте новый объект Dim3PointAngular в пространстве модели
    Set DimPointAngularObj = ThisDrawing.ModelSpace.AddDim3PointAngular(AngleVertex, FirstPoint, SecondPoint, TextPoint)
    ThisDrawing.Application.ZoomAll

    ' Читайте и показывайте текущий вес линии расширения
    CurrentSetting = DimPointAngularObj.ExtensionLineWeight
    Select Case CurrentSetting
        Case acLnWtByLayer: CurrentSetting = "By Layer"
        Case acLnWtByBlock: CurrentSetting = "By Block"
        Case acLnWtByLwDefault: CurrentSetting = "By Default"
        Case Else
    End Select
    
    MsgBox "Вес линии расширения для этого объекта в настоящее время установлен в: " & CurrentSetting

    ' Измените вес линии расширения
    DimPointAngularObj.ExtensionLineWeight = acLnWt100
    ThisDrawing.Regen acAllViewports
    
    ' Читайте и показывайте текущий вес линии расширения
    MsgBox "Вес добавочной линии для этого объекта теперь установлен в: " & DimPointAngularObj.ExtensionLineWeight
    
    ' Возвратите предыдущую установку веса линии
    ThisDrawing.preferences.LineWeightDisplay = oldLWSetting
    
End Sub