Sub Example_ExtLine1Suppress()
    ' Этот пример создает объект Dim3PointAngular в пространстве модели и
    ' подавляет добавочные линии, используя свойства ExtLine2Suppress и
    ' ExtLine1Suppress
    
    Dim DimPointAngularObj As AcadDim3PointAngular
    Dim AngleVertex(0 To 2) As Double
    Dim FirstPoint(0 To 2) As Double, SecondPoint(0 To 2) As Double
    Dim TextPoint(0 To 2) As Double
    Dim Line1Suppressed As String, Line2Suppressed As String
    
    ' Определите новый объект Dim3PointAngular
    AngleVertex(0) = 0: AngleVertex(1) = 0: AngleVertex(2) = 0
    FirstPoint(0) = 2: FirstPoint(1) = 2: FirstPoint(2) = 0
    SecondPoint(0) = 1: SecondPoint(1) = 4: SecondPoint(2) = 0
    TextPoint(0) = 6: TextPoint(1) = 6: TextPoint(2) = 0

    ' Создайте новый объект Dim3PointAngular в пространстве модели
    Set DimPointAngularObj = ThisDrawing.ModelSpace.AddDim3PointAngular(AngleVertex, FirstPoint, SecondPoint, TextPoint)
    ThisDrawing.Application.ZoomAll

    ' Читайте и показывайте текущую информацию подавления добавочной линии
    Line1Suppressed = IIf(DimPointAngularObj.ExtLine1Suppress, "подавлена", "не подавлена")
    Line2Suppressed = IIf(DimPointAngularObj.ExtLine2Suppress, "подавлена", "не подавлена")
    
    MsgBox "Первая добавочная линия " & Line1Suppressed & vbCrLf & _
           "Вторая добавочная линия " & Line2Suppressed

    ' Подавите первую добавочную линию
    DimPointAngularObj.ExtLine1Suppress = True
    ThisDrawing.Regen acAllViewports
    MsgBox "Первая добавочная линия теперь подавлена"
    
    ' Подавите вторую добавочную линию
    DimPointAngularObj.ExtLine2Suppress = True
    ThisDrawing.Regen acAllViewports
    MsgBox "Вторая добавочная линия теперь подавлена"
   
   ' Возвратите обе добавочных линии
    DimPointAngularObj.ExtLine1Suppress = False
    DimPointAngularObj.ExtLine2Suppress = False
    ThisDrawing.Regen acAllViewports
    MsgBox "Обе добавочных линии теперь снова видимы"

End Sub