Sub Example_FieldLength()
    ' Этот пример создает определение атрибута пространство модели.
    ' Затем делает запрос начального значения свойства FieldLength, изменяет
    ' значение и наконец сбрасывает значение.
    
    Dim attributeObj As AcadAttribute
    Dim height As Double
    Dim mode As Long
    Dim prompt As String
    Dim insertionPoint(0 To 2) As Double
    Dim tag As String
    Dim value As String
    
    ' Определите определение атрибута
    height = 1#
    mode = acAttributeModeVerify
    prompt = "New Prompt"
    insertionPoint(0) = 5#: insertionPoint(1) = 5#: insertionPoint(2) = 0
    tag = "New Tag"
    value = "New Value"
    
    ' Создайте объект определения атрибута в пространстве модели
    Set attributeObj = ThisDrawing.ModelSpace.AddAttribute(height, mode, prompt, insertionPoint, tag, value)
    ZoomAll
    
    ' Возвратите текущую длину поля атрибута
    Dim currFieldLength As Integer
    currFieldLength = attributeObj.FieldLength
    MsgBox "FieldLength атрибут " & attributeObj.FieldLength, vbInformation, "FieldLength Пример"
    
    ' Измените длину поля
    attributeObj.FieldLength = currFieldLength + 2
    attributeObj.Update
    MsgBox "Новый FieldLength атрибут " & attributeObj.FieldLength, vbInformation, "FieldLength Пример"
    
    ' Сбросьте длину поля к первоначальному значению
    attributeObj.FieldLength = currFieldLength
    attributeObj.Update
    MsgBox "FieldLength атрибут сброшен к " & attributeObj.FieldLength, vbInformation, "FieldLength Пример"
    
End Sub