Sub Example_GetEntity()
    ' Этот пример создает несколько объектов в пространстве модели. Затем
    ' запрашивает пользователя выбирать объект. Пример продолжает
    ' выбирать пользовательские объекты до выбора пустого пространства.
    
    ' Создайте объект Ray в пространстве модели
    Dim rayObj As AcadRay
    Dim basePoint(0 To 2) As Double
    Dim SecondPoint(0 To 2) As Double
    basePoint(0) = 3#: basePoint(1) = 3#: basePoint(2) = 0#
    SecondPoint(0) = 1#: SecondPoint(1) = 3#: SecondPoint(2) = 0#
    Set rayObj = ThisDrawing.ModelSpace.AddRay(basePoint, SecondPoint)
    
    ' Создайте объект ломаной линии в пространстве модели
    Dim plineObj As AcadLWPolyline
    Dim points(0 To 5) As Double
    points(0) = 3: points(1) = 7
    points(2) = 9: points(3) = 2
    points(4) = 3: points(5) = 5
    Set plineObj = ThisDrawing.ModelSpace.AddLightWeightPolyline(points)
    plineObj.Closed = True

    ' Создайте объект линии в пространстве модели
    Dim lineObj As AcadLine
    Dim startPoint(0 To 2) As Double
    Dim endPoint(0 To 2) As Double
    startPoint(0) = 0: startPoint(1) = 0: startPoint(2) = 0
    endPoint(0) = 2: endPoint(1) = 2: endPoint(2) = 0
    Set lineObj = ThisDrawing.ModelSpace.AddLine(startPoint, endPoint)
    
    ' Создайте объект круга в пространстве модели
    Dim circObj As AcadCircle
    Dim centerPt(0 To 2) As Double
    Dim radius As Double
    centerPt(0) = 20: centerPt(1) = 30: centerPt(2) = 0
    radius = 3
    Set circObj = ThisDrawing.ModelSpace.AddCircle(centerPt, radius)

    ' Создайте объект эллипса в пространстве модели
    Dim ellObj As AcadEllipse
    Dim majAxis(0 To 2) As Double
    Dim center(0 To 2) As Double
    Dim radRatio As Double
    center(0) = 5#: center(1) = 5#: center(2) = 0#
    majAxis(0) = 10: majAxis(1) = 20#: majAxis(2) = 0#
    radRatio = 0.3
    Set ellObj = ThisDrawing.ModelSpace.AddEllipse(center, majAxis, radRatio)

    ZoomAll
    
    ' Начните выбор
    Dim returnObj As AcadObject
    Dim basePnt As Variant
    
    On Error Resume Next
    
    ' Следующий пример ждет выбора от пользователя
RETRY:
    ThisDrawing.Utility.GetEntity returnObj, basePnt, "Выберите объект"
    
    If Err <> 0 Then
        Err.Clear
        MsgBox "Программа закончилась.", , "GetEntity Пример"
        Exit Sub
    Else
        returnObj.Update
        MsgBox "Тип объекта: " & returnObj.EntityName, , "GetEntity Пример"
        returnObj.Update
    End If
    
    GoTo RETRY
End Sub

Сайт управляется системой uCoz