Sub Example_GetRemoteFile()
    ' Этот пример запросит пользователя относительно загрузки URL. После
    ' загрузки, пример будет пытаться загружать URL как рисунок.
    '
    ' * Примечание: Не забудьте удилять загруженный файл из вашего
    ' дисковода по окончанию.
    
    Dim Utility As AcadUtility
    Dim URL As String, DestFile As String, FileURL As String
    
    Set Utility = ThisDrawing.Utility   ' Соединитесь с объектом Utility
    
GETURL:
    ' Запросите пользователя относительно URL. Это должен быть URL файла рисунка AutoCADа.
    URL = InputBox("Введите законченный URL, который Вы желаете загрузить. " & _
                    "Введите БРОУЗЕР, чтобы выбрать URL из web-браузера", _
                    "Введите URL для загрузки", URL)
    
    URL = Trim(URL)                     ' Избавьтесь от пробелов
    
    If URL = "" Then Exit Sub           ' Пользователь сделал отмену


    ' Пользователь хочет выбрать из броузера?
    If StrComp(URL, "BROWSER", vbTextCompare) = 0 Then
        Utility.LaunchBrowserDialog _
        URL, "AutoCAD Browser", "Open", "http://www.autodesk.com", "ACADBROWSER", True
        
        GoTo GETURL     ' Возвращение, чтобы показать выбранный URL и позволить модификации
    End If

    ' Определите, ввел ли пользователь допустимый URL; в противном случае подсказка снова
    If Not (Utility.IsURL(URL)) Then
        MsgBox "URL, который Вы ввели, не допустим. Удостоверьтесь, что синтаксис - допустимый."
        GoTo GETURL
    End If
        
    ' Загрузка URL
    Utility.GetRemoteFile URL, DestFile, True
    
    ' Отображение загруженного файла
    MsgBox URL & " был загружен: " & DestFile & vbCrLf & vbCrLf & _
           "Нажмите любую клавишу, чтобы попытаться загрузить новый файл."

    ' Пытайтесь загружать файл как рисунок; если ошибка происходит, он был
    ' вероятно не файлом рисунка, а скорее текстом от web-страницы.
    ' Попробуйте загрузить файл в текстовый редактор, чтобы рассмотреть содержание.
    On Error Resume Next
    ThisDrawing.Application.Documents.Open DestFile
    If Err.Number <> 0 Then
        MsgBox "Ошибка открытия загруженного файла в качестве рисунока: " & Err.Description & vbCrLf & vbCrLf & _
               "Это - не допустимый файл рисунка!"
    End If
    On Error GoTo 0
    
    ' Используйте IsRemoteFile, чтобы определить, был ли этот файл загружен от URL.
    '
    ' * Примечание: Хотя результаты возвращаемые IsRemoteFile уже
    ' известны, так как файл был загружен, важно знать, как этот метод может
    ' использоваться.
    If Utility.IsRemoteFile(DestFile, FileURL) Then
        MsgBox "Файл: " & DestFile & " является загруженным файлом и был загружен из: " & FileURL
    Else
        MsgBox "Файл: " & DestFile & " - не загружен."
    End If

End Sub

Сайт управляется системой uCoz