Sub Example_HorizontalTextPosition()
    ' Этот пример создает выровненное измерение в пространстве модели и
    ' изменяет текст через различные горизонтальные выравнивания
    
    Dim dimObj As AcadDimAligned
    Dim point1(0 To 2) As Double, point2(0 To 2) As Double
    Dim location(0 To 2) As Double
    Dim CurrentValue As String
    
    ' Определите измерение
    point1(0) = 5: point1(1) = 5: point1(2) = 0
    point2(0) = 9: point2(1) = 5: point2(2) = 0
    location(0) = 5: location(1) = 7: location(2) = 0
    
    ' Создайте выровненный объект измерения в пространстве модели
    Set dimObj = ThisDrawing.ModelSpace.AddDimAligned(point1, point2, location)
    ThisDrawing.Application.ZoomAll

    ' Читайте и показывайте текущее положение текста
    Select Case dimObj.HorizontalTextPosition
        Case acHorzCentered:        CurrentValue = "центрирован"
        Case acFirstExtensionLine:  CurrentValue = "выровненный к первой добавочной линии"
        Case acSecondExtensionLine: CurrentValue = "выровненный к второй добавочной линии"
        Case acOverFirstExtension:  CurrentValue = "выровненный по первой добавочной линии"
        Case acOverSecondExtension: CurrentValue = "выровненный по второй добавочной линии"
    End Select
    
    MsgBox "Текст измерения " & CurrentValue

    ' Вызовите выравнивание текста измерения к первой добавочной линии
    dimObj.HorizontalTextPosition = acFirstExtensionLine
    ThisDrawing.Regen acAllViewports
    MsgBox "Текст измерения теперь выровнен к первой добавочной линии"
   
    ' Вызовите выравнивание текста измерения к второй добавочной линии
    dimObj.HorizontalTextPosition = acSecondExtensionLine
    ThisDrawing.Regen acAllViewports
    MsgBox "Текст измерения теперь выровнен к второй добавочной линии"

End Sub