Sub Example_HyperLinks()
    ' Этот пример создает объект Circle в пространстве модели и добавляет
    ' нового Hyperlink к его коллекции Hyperlinks
    
    Dim Hyperlinks As AcadHyperlinks
    Dim Hyperlink As AcadHyperlink
    Dim circleObj As AcadCircle
    Dim centerPoint(0 To 2) As Double
    Dim radius As Double
    Dim HLList As String
    
    ' Определите объект Circle
    centerPoint(0) = 0: centerPoint(1) = 0: centerPoint(2) = 0
    radius = 5#
    
    ' Создайте объект Circle в пространстве модели
    Set circleObj = ThisDrawing.ModelSpace.AddCircle(centerPoint, radius)

    ThisDrawing.Application.ZoomAll
    
    ' Получите справочник к коллекции Hyperlinks Круга
    Set Hyperlinks = circleObj.Hyperlinks
    
    ' Добавьте нового Hyperlink, законченного со всеми свойствами
    Set Hyperlink = Hyperlinks.Add("AutoDesk")
    Hyperlink.URL = "www.autodesk.com"
    Hyperlink.URLDescription = "Autodesk Main Site"
    Hyperlink.URLNamedLocation = "MY_LOCATION"
    
    ' Читайте и показывайте список существующих Hyperlinks и их свойств
    ' для этого объекта
    For Each Hyperlink In Hyperlinks
        HLList = HLList & "____________________________________" & vbCrLf   ' Разделитель
        HLList = HLList & "URL: " & Hyperlink.URL & vbCrLf
        HLList = HLList & "Описание URL: " & Hyperlink.URLDescription & vbCrLf
        HLList = HLList & "URL имени местоположения: " & Hyperlink.URLNamedLocation & vbCrLf
    Next
    
    MsgBox "Круг имеет " & Hyperlinks.count & " гиперссылок: " & vbCrLf & HLList
End Sub