Sub Example_Import()
    ' Этот пример создаст новый рисунок. Убедитесь, что сохранили вашу
    ' Этот пример создает круг. Затем экспортирует рисунок в файлу по имени
    ' DXFExprt.DXF. Затем открывает новый рисунок и импортирует файл.
    
    ' Создайте круг для визуального представления
    Dim circleObj As AcadCircle
    Dim centerPt(0 To 2) As Double
    Dim radius As Double
    centerPt(0) = 2: centerPt(1) = 2: centerPt(2) = 0
    radius = 1
    Set circleObj = ThisDrawing.ModelSpace.AddCircle(centerPt, radius)
    ZoomAll
    
    ' Создайте пустой набор выбора
    Dim sset As AcadSelectionSet
    Set sset = ThisDrawing.SelectionSets.Add("TEST")
    
    ' Экспортируйте текущий рисунок в файл, указанный выше.
    Dim exportFile As String
    exportFile = "C:\my documents\DXFExprt"    ' Корректируйте путь для вашей системы
    ThisDrawing.Export exportFile, "DXF", sset
    
    ' Откройте новый рисунок
    Dim Acad As AcadApplication
    Dim newdoc As AcadDocument
    Set Acad = ThisDrawing.Application
    Set newdoc = Acad.Documents.Add("acad.dwt")
    
    ' Определите импорт
    Dim importFile As String
    Dim InsertPoint(0 To 2) As Double
    Dim scalefactor As Double
    importFile = "C:\my documents\DXFExprt.dxf"  ' Корректируйте путь для вашей системы
    InsertPoint(0) = 0#: InsertPoint(1) = 0#: InsertPoint(2) = 0#
    scalefactor = 2#
    
    ' Импортируйте файл
    ThisDrawing.Import importFile, InsertPoint, scalefactor
    ZoomAll
    
End Sub