Sub Example_LaunchBrowserDialog()
    ' Этот пример запросит пользователя относительно URL и проверит, что
    ' был введен надлежащий URL. После загрузки, пример попытается
    ' загрузить загруженный URL как рисунок.
    '
    '* Примечание: Не забудьте удалять загруженный файл из вашего дисковода.
    
    Dim Utility As AcadUtility
    Dim URL As String, DestFile As String, FileURL As String
    
    Set Utility = ThisDrawing.Utility   ' Соединитесь с объектом Utility
    
GETURL:
    'Запросите пользователя относительно URL. Это должен быть URL к файлу рисунка AutoCADа.
    URL = InputBox("Введите полный URL файла, который Вы желаете загрузить. " & _
                    "Введите BROWSER, чтобы выбрать URL из web-браузера", _
                    "Введите URL, Чтобы Загрузить", URL)
    
    URL = Trim(URL)                     ' Избавьтесь от пустых пространств
    
    If URL = "" Then Exit Sub

    'Пользователь хочет выбрать из браузера?
    If StrComp(URL, "BROWSER", vbTextCompare) = 0 Then
        Utility.LaunchBrowserDialog _
        URL, "AutoCAD Browser", "Open", "http://www.autodesk.com", "ACADBROWSER", True
        
        GoTo GETURL     ' Возвратитесь, чтобы показать выбранный URL и позволить модификации
    End If

    'Определите, ввел ли пользователь допустимый URL; в противном случае подсказка снова
    If Not (Utility.IsURL(URL)) Then
        MsgBox "URL, который Вы ввели, не допустим. Удостоверьтесь, что синтаксис - допустимый."
        GoTo GETURL
    End If
        
    'Загрузите URL
    Utility.GetRemoteFile URL, DestFile, True
    
    'Отображение информации файла
    MsgBox URL & " был загружен: " & DestFile & vbCrLf & vbCrLf & _
           "Нажмите любую клавишу, чтобы попытаться загрузить новый файл как рисунок."

    'Попытайтесь загрузить файл как рисунок; если ошибка происходит, это было вероятно не рисунком
    ' а скорее текст от web-страницы.
    'Пробуйте открыть загруженный файл в редакторе текста, чтобы рассмотреть содержание.
    On Error Resume Next
    ThisDrawing.Application.Documents.Open DestFile
    If Err.Number <> 0 Then
        MsgBox "Ошибочное открытие файла: " & Err.Description & vbCrLf & vbCrLf & _
               "Это - вероятно не допустимый файл рисунка!"
    End If
    On Error GoTo 0
    
    'Используйте IsRemoteFile, чтобы определить, был ли этот файл загружен от URL.
    'Если это было, покажите URL, от которого он был загружен
    '
    '* Примечание: Хотя результаты, которые IsRemoteFile возвратит, уже
    ' известны, потому что файл был только загружен, важно знать, как этот
    ' метод может использоваться.
    If Utility.IsRemoteFile(DestFile, FileURL) Then
        MsgBox "Файл: " & DestFile & " является загруженным файлом и был загружен от: " & FileURL
    Else
        MsgBox "Файл: " & DestFile & " не загружен. "
    End If

End Sub

Сайт управляется системой uCoz