Sub Example_RemoveItems()
    'Этот пример создает набор выбора и несколько объектов.
    'Он добавляет объекты к набору выбора и затем удаляет два объекта из набора выбора.
    
    'Создайте новый набор выбора
    Dim ssetObj As AcadSelectionSet
    Set ssetObj = ThisDrawing.SelectionSets.Add("TEST_SELECTIONSET")
    
    'Создайте объект Ray в пространстве модели
    Dim rayObj As AcadRay
    Dim basePoint(0 To 2) As Double
    Dim SecondPoint(0 To 2) As Double
    basePoint(0) = 3#: basePoint(1) = 3#: basePoint(2) = 0#
    SecondPoint(0) = 1#: SecondPoint(1) = 3#: SecondPoint(2) = 0#
    Set rayObj = ThisDrawing.ModelSpace.AddRay(basePoint, SecondPoint)
    
    'Создайте объект ломаной линии в пространстве модели
    Dim plineObj As AcadLWPolyline
    Dim points(0 To 5) As Double
    points(0) = 3: points(1) = 7
    points(2) = 9: points(3) = 2
    points(4) = 3: points(5) = 5
    Set plineObj = ThisDrawing.ModelSpace.AddLightWeightPolyline(points)
    plineObj.Closed = True

    'Создайте объект линии в пространстве модели
    Dim lineObj As AcadLine
    Dim startPoint(0 To 2) As Double
    Dim endPoint(0 To 2) As Double
    startPoint(0) = 0: startPoint(1) = 0: startPoint(2) = 0
    endPoint(0) = 2: endPoint(1) = 2: endPoint(2) = 0
    Set lineObj = ThisDrawing.ModelSpace.AddLine(startPoint, endPoint)
    
    'Создайте объект круга в пространстве модели
    Dim circObj As AcadCircle
    Dim centerPt(0 To 2) As Double
    Dim radius As Double
    centerPt(0) = 20: centerPt(1) = 30: centerPt(2) = 0
    radius = 3
    Set circObj = ThisDrawing.ModelSpace.AddCircle(centerPt, radius)

    'Создайте объект эллипса в пространстве модели
    Dim ellObj As AcadEllipse
    Dim majAxis(0 To 2) As Double
    Dim center(0 To 2) As Double
    Dim radRatio As Double
    center(0) = 5#: center(1) = 5#: center(2) = 0#
    majAxis(0) = 10: majAxis(1) = 20#: majAxis(2) = 0#
    radRatio = 0.3
    Set ellObj = ThisDrawing.ModelSpace.AddEllipse(center, majAxis, radRatio)

    ZoomAll
    
    'Выполните итерации через коллекцию пространства модели.
    'Соберите найденные объекты в массив объектов для добавления их к набору выбора.
    ReDim ssobjs(0 To ThisDrawing.ModelSpace.count - 1) As AcadEntity
    Dim I As Integer
    For I = 0 To ThisDrawing.ModelSpace.count - 1
        Set ssobjs(I) = ThisDrawing.ModelSpace.Item(I)
    Next
    
    'Добавьте массив объектов к набору выбора
    ssetObj.AddItems ssobjs
    GoSub LISTOBJS
    
    'Удалите два объекта из набора выбора
    Dim removeObjects(0 To 1) As AcadEntity
    Set removeObjects(0) = ellObj
    Set removeObjects(1) = circObj
    ssetObj.RemoveItems removeObjects
    MsgBox "Эллипс и круг были удалены из набора выбора. "
    GoSub LISTOBJS
Exit Sub
LISTOBJS:
    
        'Перечислите все объекты в наборе выбора
        If ssetObj.count = 0 Then
            MsgBox "Набор выбора пуст"
        Else
            For I = 0 To ssetObj.count - 1
                MsgBox "Набор выбора содержит: " & ssetObj.Item(I).ObjectName
            Next
        End If
        Return
    
End Sub

Сайт управляется системой uCoz