Sub Example_SetVariable()
    ' Этот пример устанавливает различные системные переменные,
    ' каждая имеет свой тип данных.
    
    Dim sysVarName As String
    Dim sysVarData As Variant
    Dim DataType As Integer
    
    ' Установите системную переменную FILEDIA (тип данных Integer) в 1.
    ' ОБРАТИТЕ ВНИМАНИЕ, что Вы должны объявить переменную c типом
    ' данных системной переменной
    Dim intData As Integer
    sysVarName = "FILEDIA"
    intData = 1
    sysVarData = intData    ' Данные Integer
    ThisDrawing.SetVariable sysVarName, sysVarData
    
    ' Проверьте переменную, используя GetVariable
    sysVarData = ThisDrawing.GetVariable(sysVarName)
    MsgBox sysVarName & " = " & sysVarData, , "SetVariable Пример"
    
    ' Установите системную переменную DCTCUST (тип данных String) в "My Custom Dictionary"
    Dim strData As String
    sysVarName = "DCTCUST"
    strData = "My Custom Dictionary"
    sysVarData = strData        ' Данные String
    ThisDrawing.SetVariable sysVarName, sysVarData
    
    ' Проверьте переменную, используя GetVariable
    sysVarData = ThisDrawing.GetVariable(sysVarName)
    MsgBox sysVarName & " = " & sysVarData, , "SetVariable Пример"
   
    ' Установите системную переменную CHAMFERA (тип данных Double) в 1.5
    Dim dataDouble As Double
    sysVarName = "CHAMFERA"
    dataDouble = 1.5
    sysVarData = dataDouble ' Двойные данные
    ThisDrawing.SetVariable sysVarName, sysVarData

    ' Проверьте переменную, используя GetVariable
    sysVarData = ThisDrawing.GetVariable(sysVarName)
    MsgBox sysVarName & " = " & sysVarData, , "SetVariable Пример"
   
    ' Установите системную переменную INSBASE (массив переменных) в (1.0,1.0,0)
    Dim arrayData3D(0 To 2) As Double
    sysVarName = "INSBASE"
    arrayData3D(0) = 1#: arrayData3D(1) = 1#: arrayData3D(2) = 0
    sysVarData = arrayData3D    ' Трехмерный массив данных
    ThisDrawing.SetVariable sysVarName, sysVarData

    ' Проверьте переменную, используя GetVariable
    sysVarData = ThisDrawing.GetVariable(sysVarName)
    MsgBox sysVarName & " = " & sysVarData(0) & ", " & sysVarData(1) & ", " & sysVarData(2), , "SetVariable Пример"
    
End Sub