Sub Example_URLDescription()
    'Этот пример создает объект Circle в пространстве модели и добавляет 
    'новый Hyperlink к коллекции Hyperlink
    
    Dim Hyperlinks As AcadHyperlinks
    Dim Hyperlink As AcadHyperlink
    Dim circleObj As AcadCircle
    Dim centerPoint(0 To 2) As Double
    Dim radius As Double
    Dim HLList As String
    
    'Определите объект Circle
    centerPoint(0) = 0: centerPoint(1) = 0: centerPoint(2) = 0
    radius = 5#
    
    'Создайте объект Circle в пространстве модели
    Set circleObj = ThisDrawing.ModelSpace.AddCircle(centerPoint, radius)

    ThisDrawing.Application.ZoomAll
    
    'Получите справочник к коллекции Hyperlink Circle
    Set Hyperlinks = circleObj.Hyperlinks
    
    'Добавьте новый Hyperlink
    Set Hyperlink = Hyperlinks.Add("AutoDesk")
    Hyperlink.URL = "www.autodesk.com"
    Hyperlink.URLDescription = "Autodesk Main Site"
    Hyperlink.URLNamedLocation = "MY_LOCATION"
    
    'Читайте и показывайте список существующих Hyperlink и их свойств для этого объекта
    For Each Hyperlink In Hyperlinks
        HLList = HLList & "____________________________________" & vbCrLf   ' Разделитель
        HLList = HLList & "URL: " & Hyperlink.URL & vbCrLf
        HLList = HLList & "Описание URL: " & Hyperlink.URLDescription & vbCrLf
        HLList = HLList & "URL Названное Местоположение: " & Hyperlink.URLNamedLocation & vbCrLf
    Next
    
    MsgBox "Круг имеет " & Hyperlinks.count & " Hyperlink: " & vbCrLf & HLList
End Sub