Sub Example_ViewToPlot()
    'Этот пример читает список доступного Named Views и показывает 
    'графический предварительный просмотр вида, отобранного пользователем. 
    'Текущий вид печатается, если в начале установлена ' * '
    '
    '* Примечание: После предварительного просмотра печати, Вы должны
    ' будете выйти из графического предварительного просмотра прежде,
    ' чем пример VBA остановится и управление будет возвращено
    
    Dim ViewList As New Collection
    Dim View As AcadView
    Dim iCount As Long
    Dim msg As String
    Dim ViewName As String, ViewNum As String
    
    'Получите список вида доступного к печати
    For Each View In ThisDrawing.Views
        ViewList.Add View
    Next
    
    'Есть ли любой названный вид, чтобы печатать
    If ViewList.count = 0 Then
        MsgBox "Нет никакого названного вида, чтобы печатать.", vbInformation
        Exit Sub
    End If
    
    'Читайте и показывайте текущий путь таблицы стиля печати
    For iCount = 1 To ViewList.count
        ViewName = ViewList(iCount).name
        
        If ViewName = ThisDrawing.ActiveLayout.ViewToPlot Then
            ViewNum = iCount
            ViewName = "*" & ViewName
        End If
        
        msg = msg & "(" & iCount & ") " & vbTab & ViewName & vbCrLf
    Next
    
    'Запросите пользователя относительно вида печати
RETRY:
    ViewNum = InputBox("Какой вид хотели бы Вы печатать?" & vbCrLf & vbCrLf & msg, "View To Plot", ViewNum)
    
    If Trim(ViewNum) = "" Then
        Exit Sub
    End If
    
    If Not (IsNumeric(ViewNum)) Then
        MsgBox "Вы должны ввести числовое значение, соответствующее одному из упомянутого выше вида.", vbExclamation
        GoTo RETRY
    End If
    
    'Рисунок, который рассматривают для печати
    ThisDrawing.ActiveLayout.ViewToPlot = ViewList(CLng(ViewNum)).name
    
    ThisDrawing.ActiveLayout.PlotType = acView
    
    'Пошлите Печать Окна
    ThisDrawing.Plot.DisplayPlotPreview acFullPreview
End Sub

Сайт управляется системой uCoz