Sub Example_VisibilityEdge1()
    'Этот пример создает 3D Грань в пространстве модели и позволяет 
    'пользователю управлять видимостью краев
    
    Dim faceObj As Acad3DFace
    Dim point1(0 To 2) As Double, point2(0 To 2) As Double, _
        point3(0 To 2) As Double, point4(0 To 2) As Double
    Dim Edge1Msg As String, Edge2Msg As String, _
        Edge3Msg As String, Edge4Msg As String
    
    'Определите четыре координаты грани
    point1(0) = 0: point1(1) = 0: point1(2) = 0
    point2(0) = 5: point2(1) = 0: point2(2) = 1
    point3(0) = 1: point3(1) = 10: point3(2) = 0
    point4(0) = 5: point4(1) = 5: point4(2) = 1
    
    'Создайте 3DFace объект в пространстве модели
    Set faceObj = ThisDrawing.ModelSpace.Add3DFace(point1, point2, point3, point4)
    ThisDrawing.Application.ZoomAll
    
    'Покажите информацию о видимости краев для этого объекта
DisplayEdgeInformation:
    Edge1Msg = IIf(faceObj.VisibilityEdge1, "Edge1 нового 3DFace видим", "Edge1 нового 3DFace не видим")
    Edge2Msg = IIf(faceObj.VisibilityEdge2, "Edge2 нового 3DFace видим", "Edge2 нового 3DFace не видим")
    Edge3Msg = IIf(faceObj.VisibilityEdge3, "Edge3 нового 3DFace видим", "Edge3 нового 3DFace не видим")
    Edge4Msg = IIf(faceObj.VisibilityEdge4, "Edge4 нового 3DFace видим", "Edge4 нового 3DFace не видим")
    
    MsgBox Edge1Msg & vbCrLf & _
           Edge2Msg & vbCrLf & _
           Edge3Msg & vbCrLf & _
           Edge4Msg
            
    'Позвольте пользователю переключать видимость одного из краев
    Select Case InputBox("Из какого края 3DFace хотели бы Вы переключать видимость?", "Toggle Edge Visibility", 1)
        Case "1": faceObj.VisibilityEdge1 = Not (faceObj.VisibilityEdge1)
        Case "2": faceObj.VisibilityEdge2 = Not (faceObj.VisibilityEdge2)
        Case "3": faceObj.VisibilityEdge3 = Not (faceObj.VisibilityEdge3)
        Case "4": faceObj.VisibilityEdge4 = Not (faceObj.VisibilityEdge4)
        Case "":  Exit Sub
        Case Else: MsgBox "Вы должны ввести число края (1-4)", vbInformation
    End Select
            
    'Вид регенерации
    ThisDrawing.Regen acAllViewports
    
    'Возвратитесь, чтобы показать информацию о краях
    GoTo DisplayEdgeInformation
End Sub

Сайт управляется системой uCoz