Sub Example_XScaleFactor()
    'Этот пример создает блок, содержащий круг.
    'Затем вставляет блок и изменяет XScaleFactor.
    
    'Создайте блок
    Dim blockObj As AcadBlock
    Dim insertionPnt(0 To 2) As Double
    insertionPnt(0) = 0#: insertionPnt(1) = 0#: insertionPnt(2) = 0#
    Set blockObj = ThisDrawing.Blocks.Add(insertionPnt, "CircleBlock")
    
    'Добавьте круг к блоку
    Dim circleObj As AcadCircle
    Dim center(0 To 2) As Double
    Dim radius As Double
    center(0) = 0: center(1) = 0: center(2) = 0
    radius = 1
    Set circleObj = blockObj.AddCircle(center, radius)
   
    'Вставьте блок
    Dim blockRefObj As AcadBlockReference
    insertionPnt(0) = 2#: insertionPnt(1) = 2#: insertionPnt(2) = 0
    Set blockRefObj = ThisDrawing.ModelSpace.InsertBlock(insertionPnt, "CircleBlock", 1#, 1#, 1#, 0)
    
    'Найдите текущий XScaleFactor для вхождения блока
    Dim currXScaleFactor As Double
    currXScaleFactor = blockRefObj.XScaleFactor
    ZoomAll
    MsgBox "Текущий XScaleFactor для вхождения блока " & blockRefObj.XScaleFactor, , "XScaleFactor Пример"
    
    'Измените XScaleFactor для вхождения блока
    blockRefObj.XScaleFactor = currXScaleFactor + 2
    ZoomAll
    MsgBox "Новый XScaleFactor для вхождения блока " & blockRefObj.XScaleFactor, , "XScaleFactor Пример"
    
End Sub