Sub Example_YScaleFactor()
    'Этот пример создает блок, содержащий круг.
    'Затем вставляет блок и изменяет YScaleFactor.
    
    'Создайте блок
    Dim blockObj As AcadBlock
    Dim insertionPnt(0 To 2) As Double
    insertionPnt(0) = 0#: insertionPnt(1) = 0#: insertionPnt(2) = 0#
    Set blockObj = ThisDrawing.Blocks.Add(insertionPnt, "CircleBlock")
    
    'Добавьте круг к блоку
    Dim circleObj As AcadCircle
    Dim center(0 To 2) As Double
    Dim radius As Double
    center(0) = 0: center(1) = 0: center(2) = 0
    radius = 1
    Set circleObj = blockObj.AddCircle(center, radius)
   
    'Вставьте блок
    Dim blockRefObj As AcadBlockReference
    insertionPnt(0) = 2#: insertionPnt(1) = 2#: insertionPnt(2) = 0
    Set blockRefObj = ThisDrawing.ModelSpace.InsertBlock(insertionPnt, "CircleBlock", 1#, 1#, 1#, 0)
    ZoomAll
    
    'Найдите текущий YScaleFactor для вхождения блока
    Dim currYScaleFactor As Double
    currYScaleFactor = blockRefObj.YScaleFactor
    MsgBox "Текущий YScaleFactor для вхождения блока " & blockRefObj.YScaleFactor, , "YScaleFactor Пример"
    
    'Измените YScaleFactor для вхождения блока
    blockRefObj.YScaleFactor = currYScaleFactor + 2
    ZoomAll
    MsgBox "Новый YScaleFactor для вхождения блока " & blockRefObj.YScaleFactor, , "YScaleFactor Пример"
    
End Sub